#!/bin/zsh
# Baut LAME 3.100 als eigene WebAssembly-Datei (ADR 0001: austauschbar statt Base64 im JS).
#
#   scripts/build-lame-wasm.sh
#
# Ergebnis:  public/wasm/lame/lame.wasm + lame.mjs (Emscripten-Lader, ES-Modul, nur Worker)
#            public/lizenzen/LAME-COPYING.txt, public/lizenzen/quellen/lame-3.100.tar.gz
#            public/lizenzen/quellen/BUILD-INFO-lame.txt (Version, SHA-256, Flags)
# Braucht:   git, curl; Emscripten holt das Skript selbst (build/toolchain/emsdk, gepinnt).
set -euo pipefail
ROOT=${0:A:h:h}
source $ROOT/scripts/lib/gemeinsam.sh
SRC=$ROOT/build/wasm-src
DL=$SRC/downloads
WORK=$SRC/lame-work
OUT=$ROOT/public/wasm/lame
LIC=$ROOT/public/lizenzen
JOBS=$(sysctl -n hw.ncpu)

LAME_VERSION=3.100
LAME_URL=https://downloads.sourceforge.net/project/lame/lame/$LAME_VERSION/lame-$LAME_VERSION.tar.gz
LAME_SHA=ddfe36cab873794038ae2c1210557ad34857a4b6bdc515785d1da9e175b1da1e

export LC_ALL=C SOURCE_DATE_EPOCH=1760572800
emsdk_bereit
fetch $LAME_URL lame-$LAME_VERSION.tar.gz $LAME_SHA
frischer_ordner $WORK
unpack lame-$LAME_VERSION.tar.gz $WORK/lame
perl -ni -e 'print unless /^lame_init_old$/' $WORK/lame/include/libmp3lame.sym

say "LAME $LAME_VERSION (Emscripten $EMSDK_VERSION)"
CFLAGS_WASM="-O3 -msimd128 -DNDEBUG"
(cd $WORK/lame && emconfigure ./configure --host=i686-pc-linux-gnu --prefix=$WORK/prefix \
   --disable-shared --enable-static --disable-frontend --disable-decoder --disable-gtktest \
   --disable-dependency-tracking CFLAGS="$CFLAGS_WASM" >/dev/null \
 && emmake make -j$JOBS >/dev/null && emmake make install >/dev/null)

mkdir -p $OUT
LINK_FLAGS=(-O3 -msimd128 -sMODULARIZE=1 -sEXPORT_ES6=1 -sEXPORT_NAME=createLame
  -sENVIRONMENT=worker -sALLOW_MEMORY_GROWTH=1 -sINITIAL_MEMORY=16777216 -sFILESYSTEM=0
  -sEXPORTED_FUNCTIONS=_malloc,_free -sEXPORTED_RUNTIME_METHODS=HEAPU8,HEAPF32,UTF8ToString
  -sDYNAMIC_EXECUTION=0 -sTEXTDECODER=2)
emcc ${=CFLAGS_WASM} -I$WORK/prefix/include $ROOT/wasm/lame/bridge.c $WORK/prefix/lib/libmp3lame.a \
  $LINK_FLAGS -o $OUT/lame.mjs
[[ -f $OUT/lame.wasm ]] || fail "lame.wasm fehlt."
# Kein eval/new Function im Lader (CSP ohne 'unsafe-eval').
if grep -qE 'new Function|eval\(' $OUT/lame.mjs; then fail "lame.mjs enthält eval/new Function."; fi
STRINGS=$(LC_ALL=C strings -a $OUT/lame.wasm $OUT/lame.mjs)
if grep -qE -- '/Users/|/private/|/Applications/' <<< "$STRINGS"; then fail "lame.wasm enthält Pfade dieses Macs."; fi

mkdir -p $LIC/quellen
cp $WORK/lame/COPYING $LIC/LAME-COPYING.txt
cp $DL/lame-$LAME_VERSION.tar.gz $LIC/quellen/
WASM_SHA=$(sha_of $OUT/lame.wasm)
cat > $LIC/quellen/BUILD-INFO-lame.txt <<INFO
LAME $LAME_VERSION als WebAssembly (lame.wasm) — LGPL 2.0 oder später.
Quelle: $LAME_URL
SHA-256 Quelle: $LAME_SHA
Emscripten: $EMSDK_VERSION (emsdk-Commit $EMSDK_COMMIT)
configure: --host=i686-pc-linux-gnu (nur damit das alte config.sub cross-kompiliert; CC=emcc, kein Assembler) --disable-shared --enable-static --disable-frontend --disable-decoder
CFLAGS: $CFLAGS_WASM
Link: ${LINK_FLAGS[*]}
Brücke: bridge.c (in diesem Ordner), Bauskript: build-lame-wasm.sh, gemeinsam.sh
SHA-256 lame.wasm: $WASM_SHA
Änderung an der Quelle: include/libmp3lame.sym ohne Zeile lame_init_old (Symbol existiert nicht).
INFO
cp $ROOT/wasm/lame/bridge.c $LIC/quellen/lame-bridge.c
cp $ROOT/scripts/build-lame-wasm.sh $LIC/quellen/
cp $ROOT/scripts/lib/gemeinsam.sh $LIC/quellen/
say "fertig: $(ls -l $OUT/lame.wasm | awk '{print $5}') Bytes, SHA-256 $WASM_SHA"
